Classes.DeallocateHWnd Function

Frees a window that was created using AllocateHWnd.

Pascal

procedure DeallocateHWnd(Wnd: HWND);

C++

DeallocateHWnd(HWND Wnd);

File

Classes

Description

Call DeallocateHWnd to free a window that was created using the AllocateHWnd function. Windows must be freed to release the system resources that they consume.

The Wnd parameter is the window handle of the window to be freed. This value is the same as the handle returned by the call to AllocateHWnd.

Warning: Do not use DeallocateHWnd on the handle of a windowed control. Windowed controls free their handles using the protected DestroyHandle method, which ensures that the control is left in a consistent state.

Delphi Examples:

Copy Code

{
The following code is from the implementation of TTimer. It
shows how the timer component’s constructor creates a hidden
window to respond to Timer messages and how the destructor
frees that window.
}
{
TTimer implements a WndProc method that becomes the window
procedure for the hidden window.
}
procedure MyTTimer.WndProc(var Msg: TMessage);
begin
  with Msg do
    if Msg = WM_TIMER then { check for timer messages }
      try
        Timer; { this calls the OnTimer event handler }
      except
        Application.HandleException(Self);
      end
    else
 { Any other messages are passed to DefWindowProc, which
 tells Windows to handle the message.
 Note that the first parameter, FWindowHandle, is the handle
 of the window receiving this message. It is obtained from the
 call to AllocateHWnd in the constructor. }
      Result := DefWindowProc(FWindowHandle, Msg, wParam, lParam);
end;
{
The TTimer constructor uses AllocateHWnd to create the
window and save its handle.
}
constructor MyTTimer.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FEnabled := True;
  FInterval := 1000;
  FWindowHandle := AllocateHWnd(WndProc);
end;

{ The TTimer destructor calls DeallocateHWnd to free the hidden window. }
destructor MyTTimer.Destroy;
begin
  FEnabled := False;
//  UpdateTimer; done by TTimer Destroy
  DeallocateHWnd(FWindowHandle);
  inherited Destroy;
end;