TStack Class

Last in, first out stack.

Pascal

TStack<T> = class(TEnumerable<T>);

C++

template <T>
class TStack : public TEnumerable<T>;

File

Generics.Collections

Description

TStack represents a last in, first out stack of the same type. It is of arbitrary size, expanding as needed. You can push nil on the stack.

When the stack changes, an OnNotify event is generated.

Count contains the number of stack entries.

The class TObjectStack inherits from TStack and provides an automatic mechanism for freeing objects removed from stacks.

Delphi Examples:

Copy Code

{
This example demonstrates the usage of the generic TStack class.
}
procedure TForm3.Button1Click(Sender: TObject);
var
  Stack: TStack<String>;
begin
  { Create a new stack }
  Stack := TStack<String>.Create();

  { Register a notification call-back }
  Stack.OnNotify := StackChanged;

  { Push some items up the stack }
  Stack.Push('John');
  Stack.Push('Mary');
  Stack.Push('Bob');
  Stack.Push('Anna');
  Stack.Push('Erica');

  { Show the last pushed element without modifying the stack }
  MessageDlg('Last pushed element is: "' + Stack.Peek() + '".', mtInformation, [mbOK], 0);

  { Extract the top element: "John" }
  Stack.Extract();

  { Reduce the capacity }
  Stack.TrimExcess();

  { The remaining count of elements }
  MessageDlg('The stack contains ' + IntToStr(Stack.Count) + ' elements.', mtInformation, [mbOK], 0);

  { Show the last pushed element by modifying the stack }
  MessageDlg('Last pushed element is: "' + Stack.Pop() + '".', mtInformation, [mbOK], 0);

  { Clear the stack }
  Stack.Clear();

  { Destroy the stack completely }
  Stack.Free;
end;

procedure TForm3.StackChanged(Sender: TObject; const Item: String; Action: TCollectionNotification);
begin
  { This method is called by the Stack everytime a change occurs }
  if Action = cnAdded then
     MessageDlg('Element added: ' + Item, mtInformation, [mbOK], 0)
  else if Action = cnRemoved then
     MessageDlg('Element removed: ' + Item, mtInformation, [mbOK], 0)
  else if Action = cnExtracted then
     MessageDlg('Element extracted: ' + Item, mtInformation, [mbOK], 0)
end;